;fill DIN_TITLE - GEN-TITLE-SHEET (CADforum.cz, 2022)

(setq MT_TitleName "ISO_TITLEA") ; or "DIN_TITLE" or "ISO_TITLEA" or "CSN_TITLEA"...
(setq MT_TagName "GEN-TITLE-SHEET{11.8}") ; or "GEN-TITLE-SHEET{2.62}" or "GEN-TITLE-SHEET{11.8}" ...

(vl-load-com)
(defun C:MechTitle ( / lo att ss ssl itm ent obj)
	(if (setq ss (ssget "_X" (list (cons 0 "INSERT")(cons 2 MT_TitleName))))
	 (progn
       (setq ssl (sslength ss)  itm -1)
	   (while (< (setq itm (1+ itm)) ssl)
	    (setq obj (vlax-ename->vla-object (setq ent (ssname ss itm))))
		(setq lo (cdr (assoc 410 (entget ent))))
	    (setq att (assoc
                   (strcase MT_TagName)
                   (mapcar
                     (function
                       (lambda (j)
                         (list (vla-get-tagstring j)(vla-get-textstring j) j)
                       )
                     )
                     (vlax-invoke obj 'GetAttributes)
                   )
                  )
        )
        (if att (progn
	      (princ (strcat "\nChanging '" (cadr att) "' to '" lo "'"))
	      (vla-put-textstring (caddr att) lo)
		 ) ; else
		  (princ (strcat "\n" MT_TagName " not found in " MT_TitleName " on " lo))
	    ) ; if att
	   ) ; while
	)
	 (princ (strcat "\nNo title blocks " MT_TitleName))
	) ; if ss
  (princ)
)